Цель очереди приоритетов - C ++?

Для std:: priority_queue, если вы используете ARC, вы должны пройти 90% пути. Контейнер STL будет автоматически хранить сильные ссылки. ВЫИГРАТЬ!

Вам нужно будет создать собственный класс сравнения.

typedef std::priority_queue<MyClass *, std::vector<MyClass *>, MyClassCompare> MyPriorityQueue;

Я не совсем уверен, как вы захотите реализовать свой класс сравнения. Это будет выглядеть примерно так:

class MyClassCompare {
    bool operator()(MyClass *lhs, MyClass *rhs) const {
        // magic!!! Be sure to return a bool.
    }
};

Пример класса оболочки

MyClassQueue.h

@interface MyClassQueue : NSObject
@property (nonatomic, readonly) MyClass *topObject;
@property (nonatomic, readonly) NSUInteger count;
- (void)pushObject:(MyClass *)myObject;
- (void)popObject;
- (void)popAllObjects;
@end

MyClassQueue.mm

#import "MyClassQueue.h"
#include <queue>
#import "MyClass.h"

class MyClassCompare {
    bool operator()(MyClass *lhs, MyClass *rhs) const {
        // magic!!! Be sure to return a bool.
    }
};

typedef std::priority_queue<MyClass *, std::vector<MyClass *>, MyClassCompare> MyPriorityQueue;

@interface MyClassQueue ()
@property (nonatomic) MyPriorityQueue *queue;
@end
@implementation MyClassQueue

- (MyClass *)topObject {
    return !self.queue->empty() ? self.queue->top() : nil;
}

- (NSUInteger)count {
    return (NSUInteger)self.queue->size();
}

- (void)pushObject:(MyClass *)myObject {
    self.queue->push(myObject);
}

- (void)popObject {
    if (!self.queue->empty()) {
        self.queue->pop();
    }
}

- (void)popAllObjects {
    if (!self.queue->empty()) {
        delete _queue;
        _queue = new MyPriorityQueue();
    }
}

- (instancetype)init {
    self = [super init];
    if (self != nil) {
        _queue = new MyPriorityQueue();
    }
    return self;
}

- (void)dealloc {
    delete _queue;
    _queue = NULL;
}    
@end