Как включить буквальную двойную кавычку в пользовательскую команду CMake?

Очевидный выбор - часто рекомендуемый при выходе за границы COMMAND, особенно со старыми версиями CMake - это использовать внешний скрипт.

Я просто хотел добавить несколько простых COMMAND вариантов, которые действительно работают и не нуждаются в оболочке, но, я должен признать, все еще частично зависят от платформы.

• Один из примеров - поместить в переменную только указанную в кавычках часть:

  set(vars_as_string "-Ldir -Ldir2")
  add_custom_target(
      QuotedEnvVar
      COMMAND env LD_FLAGS=${vars_as_string} | grep LD_FLAGS
  )
  

  Что на самом деле избегает пробела, а не кавычек.

• Другой пример - добавить его с экранированными кавычками в качестве правила запуска:

  add_custom_target(
      LauncherEnvVar
      COMMAND env | grep LD_FLAGS
  )
  set_target_properties(
      LauncherEnvVar 
      PROPERTIES RULE_LAUNCH_CUSTOM "env LD_FLAGS=\"-Ldir -Ldir2\""
  )
  

Изменить : добавлены примеры для нескольких аргументов в кавычках без необходимости экранирования кавычек.

• Другой пример - «скрыть некоторую сложность» в функции и - если вы хотите добавить это ко всем своим пользовательским вызовам команд - использовать каталог global / RULE_LAUNCH_CUSTOM:

  function(set_env)
      get_property(_env GLOBAL PROPERTY RULE_LAUNCH_CUSTOM)
      if (NOT _env)
          set_property(GLOBAL PROPERTY RULE_LAUNCH_CUSTOM "env")
      endif()
      foreach(_arg IN LISTS ARGN)
          set_property(GLOBAL APPEND_STRING PROPERTY RULE_LAUNCH_CUSTOM " ${_arg}")
      endforeach()
  endfunction(set_env)
  
  set_env(LDFLAGS="-Ldir1 -Ldir2" CFLAGS="-Idira -Idirb")
  
  add_custom_target(
      MultipleEnvVar
      COMMAND env | grep -E 'LDFLAGS|CFLAGS'
  )
  

Альтернатива (для CMake> = 3.0)

• Я думаю, то, что мы действительно ищем здесь (помимо cmake -E env ...), называется Аргумент скобки и разрешает любой символ без необходимости добавления обратной косой черты:

  set_property(
      GLOBAL PROPERTY 
          RULE_LAUNCH_CUSTOM [=[env LDFLAGS="-Ldir1 -Ldir2" CFLAGS="-Idira -Idirb"]=]
  )
  add_custom_target(
      MultipleEnvVarNew
      COMMAND env | grep -E 'LDFLAGS|CFLAGS'
  )
  

Ссылки

• 0005145: установить переменные среды для ADD_CUSTOM_COMMAND / ADD_CUSTOM_TARGET
• Как изменить переменные среды, передаваемые в настраиваемую цель CMake?
• [CMake] Как установить переменную среды для пользовательской команды
• cmake: когда заключать в кавычки переменные?