Итак, у меня есть следующие функции:

intercalate' :: [a] -> [[a]] -> [a]
intercalate' xs xss = concat (intersperse' xs xss)

intersperse'             :: a -> [a] -> [a]
intersperse' _   []      = []
intersperse' sep (x:xs)  = x : prependToAll' sep xs

prependToAll'            :: a -> [a] -> [a]
prependToAll' _   []     = []
prependToAll' sep (x:xs) = sep : x : prependToAll' sep xs


encodeWord :: Table -> String -> Maybe Code
encodeWord table str = intercalate' [Silence, Silence]
    <$> mapM (\x -> lookup x table) str

Для этих данных:

module Types where

data Atom = Beep | Silence
  deriving (Eq, Show)

type Code = [Atom]

dit, dah, shortGap, mediumGap :: Code
dit       = [Beep, Silence]
dah       = [Beep, Beep, Beep, Silence]
shortGap  = replicate (3-1) Silence
mediumGap = replicate (7-1) Silence

morseCode :: Char -> Code
morseCode 'A' = dit ++ dah
morseCode 'B' = dah ++ dit ++ dit ++ dit
morseCode 'C' = dah ++ dit ++ dah ++ dit
morseCode 'D' = dah ++ dit ++ dit
morseCode 'E' = dit
morseCode 'F' = dit ++ dit ++ dah ++ dit
morseCode 'G' = dah ++ dah ++ dit
morseCode 'H' = dit ++ dit ++ dit ++ dit
morseCode 'I' = dit ++ dit
morseCode 'J' = dit ++ dah ++ dah ++ dah
morseCode 'K' = dah ++ dit ++ dah
morseCode 'L' = dit ++ dah ++ dit ++ dit
morseCode 'M' = dah ++ dah
morseCode 'N' = dah ++ dit
morseCode 'O' = dah ++ dah ++ dah
morseCode 'P' = dit ++ dah ++ dah ++ dit
morseCode 'Q' = dah ++ dah ++ dit ++ dah
morseCode 'R' = dit ++ dah ++ dit
morseCode 'S' = dit ++ dit ++ dit
morseCode 'T' = dah
morseCode 'U' = dit ++ dit ++ dah
morseCode 'V' = dit ++ dit ++ dit ++ dah
morseCode 'W' = dit ++ dah ++ dah
morseCode 'X' = dah ++ dit ++ dit ++ dah
morseCode 'Y' = dah ++ dit ++ dah ++ dah
morseCode 'Z' = dah ++ dah ++ dit ++ dit
morseCode '1' = dit ++ dah ++ dah ++ dah ++ dah
morseCode '2' = dit ++ dit ++ dah ++ dah ++ dah
morseCode '3' = dit ++ dit ++ dit ++ dah ++ dah
morseCode '4' = dit ++ dit ++ dit ++ dit ++ dah
morseCode '5' = dit ++ dit ++ dit ++ dit ++ dit
morseCode '6' = dah ++ dit ++ dit ++ dit ++ dit
morseCode '7' = dah ++ dah ++ dit ++ dit ++ dit
morseCode '8' = dah ++ dah ++ dah ++ dit ++ dit
morseCode '9' = dah ++ dah ++ dah ++ dah ++ dit
morseCode '0' = dah ++ dah ++ dah ++ dah ++ dah
morseCode  _  = undefined -- Avoid warnings

type Table = [(Char, Code)]

morseTable :: Table
morseTable = [ (c , morseCode c) | c <- ['A'..'Z']++['0'..'9'] ]

Функция encodeWord работает по назначению.

Пример: Вход: "HELLO" Выход: [Beep,Silence,Beep,Silence,Beep,Silence,Beep,Silence,Silence,Silence,Beep,Silence,Silence,Silence,Beep,Silence,Beep,Beep,Beep,Silence,Beep,Silence,Beep,Silence,Silence,Silence,Beep,Silence,Beep,Beep,Beep,Silence,Beep,Silence,Beep,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Beep,Beep,Beep,Silence,Beep,Beep,Beep,Silence]

Теперь я пытаюсь определить новую функцию: encodeWords.

Пример: Вход: ["HI","THERE"] Выход: [Beep,Silence,Beep,Silence,Beep,Silence,Beep,Silence,Silence,Silence,Beep,Silence,Beep,Silence,Silence,Silence,Silence,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Beep,Silence,Beep,Silence,Beep,Silence,Beep,Silence,Silence,Silence,Beep,Silence,Silence,Silence,Beep,Silence,Beep,Beep,Beep,Silence,Beep,Silence,Silence,Silence,Beep,Silence]

Пока что я сделал это.

encodeWords :: Table -> [String] -> Maybe Code
encodeWords table stringList = intercalate' [Silence, Silence, Silence,Silence,Silence,Silence]
    <$> mapM (\x -> encodeWord table x ) stringList

Я надеялся, что последняя функция будет иметь сигнатуру типа:

Table -> [String] -> Code

Для encodeWord мне удалось запрограммировать только Table -> [String] -> Maybe Code. Я пробовал использовать fromJust вот так:

import Data.Maybe    
encodeWord :: Table -> String -> Code
encodeWord table str = fromJust (intercalate' [Silence, Silence]
    <$> mapM (\x -> lookup x table) str)

Это сработало, однако я могу использовать только Prelude и Data.Char для программы, которую пишу.

Когда я попробовал:

fromJust          :: HasCallStack => Maybe a -> a
fromJust Nothing  = error "Maybe.fromJust: Nothing" -- yuck
fromJust (Just x) = x

type HasCallStack = (?callStack :: CallStack) 

encodeWord :: Table -> String -> Code
encodeWord table str = fromJust (intercalate' [Silence, Silence]
        <$> mapM (\x -> lookup x table) str)

Я только что получил эту ошибку:

   Operator applied to too few arguments: ?
   |
59 | type HasCallStack = (?callStack :: CallStack)
   |                      ^
Failed, one module loaded.

Есть ли простой способ реализовать fromJust самостоятельно, просто используя Data.Char и Prelude?

Таким образом, я пытаюсь реализовать fromJust самостоятельно и заставить эту функцию работать:

encodeWords :: Table -> [String] -> Maybe Code
encodeWords table stringList = intercalate' [Silence, Silence, Silence,Silence,Silence,Silence]
    <$> mapM (\x -> encodeWord table x ) stringList

Я не уверен, следует ли мне применять Map, MapM или что-то еще, чтобы применить encodeWord к каждой из строк в списке. После этого encodeWords должен добавить 6 Silence между выходными данными Code для каждой строки во входном списке.

1
Inquirer 17 Ноя 2020 в 22:12

2 ответа

Лучший ответ

Это прекрасно работающая политика управления ошибками: возвращать Nothing, если что-то не так, и вы можете каскадировать это.

В самом конце вы всегда можете передать результат через fromJust и понести последствия, если будет введен недопустимый ввод. Как упоминал HaskellFreak, ваша версия fromJust выглядит нормально.

Этот код вроде работает:

myFromJust :: Maybe a -> a
myFromJust  Nothing   =  error "Maybe.fromJust: Nothing" -- yuck
myFromJust  (Just x)  =  x
    
encodeWord :: Table -> String -> Maybe Code
encodeWord table str = (intercalate' [Silence, Silence]
                          <$> mapM (\x -> lookup x table) str)

Тестирование под ghci:

 λ> 
 λ> encodeWord morseTable "ABC"
Just [Beep,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Beep,Silence,Beep,Silence,Beep,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Beep,Silence,Beep,Beep,Beep,Silence,Beep,Silence]
 λ> 
 λ> 
 λ> encodeWord morseTable "ABC+"
 Nothing
 λ>

Теперь пытаемся закодировать функцию более высокого уровня encodeWords:

Если мы начнем с простой конструкции map:

 λ> 
 λ> stringList = ["ATTACK","AT","DAWN"]
 λ> 
 λ> :type (map (encodeWord morseTable) stringList)
 (map (encodeWord morseTable) stringList) :: [Maybe Code]
 λ>

Итак, у нас есть объект [Maybe Code]. Учитывая сигнатуру типа intercalate', мы бы предпочли Maybe [Code].

 λ> 
 λ> :type mapM
mapM :: (Traversable t, Monad m) => (a -> m b) -> t a -> m (t b)
 λ> 

Итак, если тип a совпадает с m b, а крайний левый параметр функции принимается равным id, мы видим, что mapM может поменять местами конструкцию списка с элементом Maybe . Как в: (m b -> m b) -> t (m b) -> m (t b).

 λ> 
 λ> :type (mapM id)
(mapM id) :: (Traversable t, Monad m) => t (m b) -> m (t b)
 λ> 
 λ> :type (mapM id $ map (encodeWord morseTable) stringList)
 (mapM id $ map (encodeWord morseTable) stringList) :: Maybe [Code]
 λ> 
 λ> 
 λ> sil6 = replicate 6 Silence
 λ> 
 λ> :type  ((intercalate' sil6) <$> mapM id (map (encodeWord morseTable) stringList))
  ((intercalate' sil6) <$> mapM id (map (encodeWord morseTable) stringList))
  :: Maybe [Atom]
 λ> 

Так что это может быть действительный код для encodeWords:

encodeWords :: Table -> [String] -> Maybe Code
encodeWords table stringList =
    let  sil6 = replicate 6 Silence
    in
         intercalate' sil6
             <$>  (mapM id  $  map (encodeWord table) stringList)

Тестирование под ghci:

 λ> 
 λ> length $ myFromJust (encodeWords morseTable stringList)
 112
 λ> (encodeWords morseTable stringList)
 Just [Beep,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Beep,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Beep,Silence,Beep,Beep,Beep,Silence,Beep,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Beep,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Silence,Silence,Silence,Silence,Beep,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Silence,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Beep,Silence,Beep,Silence,Silence,Silence,Beep,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Beep,Silence,Beep,Beep,Beep,Silence,Beep,Beep,Beep,Silence,Silence,Silence,Beep,Beep,Beep,Silence,Beep,Silence]
 λ> 

Обратите внимание, что в этом контексте mapM id - это то же самое, что и библиотечная функция sequence :: Monad m => t (ma) -> m (ta), который определенно входит в набор Prelude.

В интересах полного раскрытия информации библиотека Prelude также включает функцию traverse , что является своего рода игрой между sequence и map. Таким образом, вы можете написать более элегантную версию encodeWords, например:

encodeWords2 :: Table -> [String] -> Maybe Code
encodeWords2 table stringList =
    let  sil6 = replicate 6 Silence
    in   intercalate' sil6  <$>  traverse (encodeWord table) stringList
3
jpmarinier 18 Ноя 2020 в 10:52

Написанное вами определение fromJust происходит непосредственно из Data.Maybe. Это не будет работать без простой модификации:

fromJust :: Maybe a -> a
fromJust Nothing = error "fromJust: Nothing"
fromJust (Just x) = x

Как вы можете видеть, соответствие шаблону fromJust в конструкторах типа данных Maybe, как вы это сделали для morseCode.

Для получения дополнительной информации о сопоставлении с образцом см .: http://learnyouahaskell.com/syntax-in-functions

3
HaskellFreak 17 Ноя 2020 в 20:02