Я использую эту формулу для подсчета слова красный за последние 30 дней, но диапазон не меняется при добавлении новой строки внизу.

Как изменить формулу, чтобы при добавлении новой строки внизу диапазон корректировался автоматически? Количество проверяемых строк всегда равно 30.

=COUNTIF(D2433:D2463, "Red")
0
Camberra CacaitA 2 Сен 2017 в 23:23

4 ответа

Лучший ответ

Используйте следующее:

=COUNTIF(OFFSET($D$2433,0,0,30,1),"Red") 

Ссылки, которые вы используете от $ 2433 до $ 2463, считаются с 31, если вам нужно 31 изменить в приведенной выше формуле с 30 на 31
Смещение начнется с $ D $ 2433 и будет отсчитывать строки в том же столбце
Контиф будет считать если красный

< Сильный > Обновление
Если в столбце D вы вводите только данные для подсчета, вы можете использовать:

=COUNTIF(OFFSET(INDIRECT("$D$"&MAX(IF($D:$D<>"",ROW($D:$D),0))),0,0,-30,1),"Red")

Это формула массива, нажмите Ctrl + Shift + Enter вместо простого Enter
Новая формула найдет последнюю непустую строку в столбце D, а Indirect автоматически исправит формулу

0
yass 3 Сен 2017 в 20:52

Другой метод использует динамический именованный диапазон :

  1. Formula > Name Manager > New: сначала дайте Имя, а затем вставьте следующую формулу в поле Referes to. Также смотрите картинку.

=INDEX(Sheet1!A:A,1):INDEX(Sheet1!A:A,INDEX(MAX((Sheet1!$A:$A<>"")*(ROW(Sheet1!A:A))),0))

Это должно дать вам диапазон как $A$1:$A$300 зависит от того, где находится последняя непустая ячейка.

  1. Теперь в ячейке, которую вы хотите оценить, добавьте эту формулу:

=COUNTIF(rng,"red")

Обратите внимание, rng - это именованный диапазон, который вы должны изменить на имя, которое хотите использовать.

Это позволит найти последнюю ячейку и даже работать на пустые ячейки. Попробуйте и дайте мне знать, если у вас есть какие-либо вопросы.

enter image description here

1
ian0411 2 Сен 2017 в 21:24
=COUNTIF(INDEX(D:D,AGGREGATE(14,6,ROW(D:D)/--((D:D)<>""),1)-30):INDEX(D:D,AGGREGATE(14,6,ROW(D:D)/--((D:D)<>""),1)),"Red")

Условия:

Там все строки под последней строкой должны быть пустыми. Не может быть ни одной пустой строки в последних 30 строках или ваш счетчик может быть выключен.

Это функция типа массива. Если вы используете ссылки на полный диапазон, он проверяет 1048576 ячеек каждый раз, когда агрегатная функция ссылается на полный диапазон столбцов. Таким образом, если вы часто используете формулу, вы можете перегружать свой компьютер, если вы используете ее только пару раз, у вас, вероятно, все будет в порядке.

0
Forward Ed 3 Сен 2017 в 00:21

Вам нужна относительная ссылка на ячейку. Вы можете сделать это с

=OFFSET()

Функция .

0
JensS 2 Сен 2017 в 20:37