Я пытаюсь написать простой код, который берет некоторые объекты с одним и тем же родительским абстрактным классом, сохраняет их в двоичный файл и считывает их обратно.

Мой код выглядит так:

module m
    implicit none

    type :: container
        class(a), allocatable :: item
    end type container

    type, abstract :: a
        character(20), public :: obj_type
        integer, public :: num
    contains
        procedure :: write_impl => write_a
        procedure :: read_impl => read_a

        generic            :: write(unformatted) => write_impl
        generic            :: read(unformatted)  => read_impl
    end type a

    type, extends(a) :: b
        integer, public :: num2
    contains
        procedure :: write_impl => write_b
        procedure :: read_impl => read_b
   end type b

    type, extends(a) :: c
    end type c

contains

    subroutine write_a(this, unit, iostat, iomsg)
        class(a), intent(in)    :: this
        integer, intent(in)         :: unit
        integer, intent(out)        :: iostat
        character(*), intent(inout) :: iomsg

        write(unit, iostat=iostat, iomsg=iomsg) this%num
    end subroutine write_a

    subroutine read_a(this, unit, iostat, iomsg)
        class(a), intent(inout) :: this
        integer, intent(in)         :: unit
        integer, intent(out)        :: iostat
        character(*), intent(inout) :: iomsg

        read(unit, iostat=iostat, iomsg=iomsg) this%num
    end subroutine read_a

    subroutine write_b(this, unit, iostat, iomsg)
        class(b), intent(in)    :: this
        integer, intent(in)         :: unit
        integer, intent(out)        :: iostat
        character(*), intent(inout) :: iomsg

        write(unit, iostat=iostat, iomsg=iomsg) this%num, this%num2
    end subroutine write_b

    subroutine read_b(this, unit, iostat, iomsg)
        class(b), intent(inout) :: this
        integer, intent(in)         :: unit
        integer, intent(out)        :: iostat
        character(*), intent(inout) :: iomsg

        read(unit, iostat=iostat, iomsg=iomsg) this%num, this%num2
    end subroutine read_b
end module m

program mwe
    use m

    implicit none

    class(a), allocatable :: o1, o2, o3, o4
    class(container), allocatable :: arr(:)
    integer :: i, arr_size, tmp
    character(20) :: str_tmp

    o1 = b('b', 1, 2)
    o2 = c('c', 3)

    allocate(arr(2))
    arr(1)%item = o1
    arr(2)%item = o2

    select type(t => o1)
        type is(b)
        write(*,*) t%num, t%num2
    end select

    select type(t => arr(1)%item)
        type is(b)
        write(*,*) t%num, t%num2
    end select

    write(*,*) 'Write into binary'
    ! WRITE size
    open(123, file='test5.dat', form='unformatted')
    write(123) SIZE(arr)

    do i=1,2 
        write(123) arr(i)%item%obj_type
            if(arr(i)%item%obj_type .eq. 'b') then
                select type(t => arr(i)%item)
                    type is(b)
                    write(123) t
                end select
            else if(arr(i)%item%obj_type .eq. 'c') then
                select type(t => arr(i)%item)
                    type is(c)
                    write(123) t
                end select
            end if
    end do
    close(123)

    write(*,*) 'Read from binary'
    open(123, file='test5.dat', form='unformatted')
    read(123) arr_size
    write(*,*) 'array size: ', arr_size

    do i=1,2
        read(123) str_tmp
        write(*,*) str_tmp
        if(allocated(o3)) deallocate(o3)
        if(str_tmp .eq. 'b') then
            allocate(b :: o3)
            select type(t => o3)
                type is(b)
                read(123) t
                write(*,*) t%num, t%num2  ! BAD OUTPUT
            end select
        else if(str_tmp .eq. 'c') then
            allocate(c :: o3)
            select type(t => o3)
                type is(c)
                read(123) t
                write(*,*) t%num
            end select
        end if

    end do

end program mwe

Проблема с чтением o1 - это тип b, т.е. этот объект имеет два компонента - num и num2. Я сохраняю его и, естественно, ожидаю, что прочитанные значения будут такими же, как и записанные.

Но у меня такое же странное поведение, как описано в Переменные, удаляемые в массивах Fortran? < / а>. В этом вопросе это было вызвано неправильным синтаксисом присваивания при инициализации массива, но в этом случае я совершенно не понимаю, почему мой результат выглядит так:

           1           2
           1           2
 Write into binary
 Read from binary
 array size:            2
 b                   
           1           0
 c                   
           3

Значения под b, очевидно, должны быть 1 и 2, а не 1 и 0. Что я делаю не так?

3
Eenoku 9 Июн 2018 в 16:35

1 ответ

Лучший ответ

Проблема здесь в том, что в

select type(t => arr(i)%item)
type is(b)
  write(123) t
end select

Ifort на самом деле не выбирает процедуру write_b для обработки определенного вывода. Он также не выбирает процедуру read_b, когда дело доходит до обработки определенного ввода.

Вместо этого выбираются процедуры write_a и read_a.

Это проблема компилятора, о которой следует сообщить в Intel. Довольно утомительный обходной путь - select type в этих процедурах.

2
francescalus 9 Июн 2018 в 15:25