Мне нужно вызвать функцию ColdFusion (присутствующую в файле .cfm), когда пользователь щелкает ссылку. И я бы хотел сделать это с помощью jQuery. У меня есть фрагмент jQuery, который выглядит так:

<script type="text/javascript">
$(document).ready(function(){
       $("td.ViewLink a").click(function(event){
         event.preventDefault();

)}

Я новичок в jQuery и AJAX, поэтому могу показаться здесь наивным. Следует ли использовать AJAX для вызова функции ColdFusion? Что-то вроде запроса на выполнение определенной функции на сервере.

Любая помощь в этом отношении приветствуется.

Приветствия .

14
Arnkrishn 16 Июн 2009 в 07:57

6 ответов

Лучший ответ

Если в вашем cfm есть несколько функций (даже если у вас их нет), поместите их в cfc. Затем вы можете использовать следующий шаблон URL-адреса для вызова определенного метода.

Cfc с именем myEntityWS.cfc

<cfcomponent>
  <cffunction name="updateDescription" access="remote" returntype="string">
    <cfargument name="value" type="string" required="yes">
    <cftry>
      your code here
    <cfcatch>
      <cfoutput>
        #cfcatch.Detail#<br />
        #cfcatch.Message#<br />
        #cfcatch.tagcontext[1].line#:#cfcatch.tagcontext[1].template#
      </cfoutput>
    </cfcatch>
    </cftry>
  </cffunction>
</cfcomponent>

Javascript

$.get('myEntityWS.cfc?method=updateDescription&value=someValue');
17
antony.trupe 16 Июн 2009 в 04:08

Вы не можете делать именно то, что пытаетесь сделать в своем примере кода. Однако у вас есть несколько вариантов.

Метод 1. Удаленно доступный объект

Переместите свои функции в CFC и получите к ним доступ через URL-адрес CFC. Этот метод доступа требует, чтобы функция использовала атрибут разрешения access='remote' - если он установлен как общедоступный (по умолчанию) или частный (или пакет, или любые уровни ролей и т. Д.), Вы получите ошибку "метод не найден" при попытке получить к нему удаленный доступ.

Делая это, вы создаете веб-сервис SOAP и потребляете его через AJAX. Вы делаете это, используя следующий формат в своем запросе jQuery:

http://domain.com/path/to/your.cfc?method=functionName&argument1=arg1Val&foo=bar&...

Если у вас есть ColdFusion 8, вы также можете указать аргумент url returnFormat='format', который будет на лету преобразовывать любые собственные объекты данных ColdFusion, которые вы возвращаете, в запрошенный формат. Он поддерживает JSON, XML и WDDX.

foo.cfc

<cfcomponent output="false">
  <cffunction name="foobar" output="false" access="remote" hint="...">
    <cfargument name="arg1" type="string" required="true" />
    ...
    <cfreturn someVar />
  </cffunction>
</cfcomponent>

Доступ по URL:

http://domain.com/path/to/foo.cfc?method=foobar&arg1=some%20value&returnFormat=JSON



Метод 2. Удаленный прокси-объект

Отрицательная сторона подхода №1 заключается в том, что создание экземпляров CFC снижает эффективность, поэтому, если этот конкретный метод AJAX будет запускаться очень часто и / или ваш CFC содержит более нескольких методов или длиннее пары сотен строк , вы не хотите создавать его снова и снова для каждого запроса. Вместо этого вы можете посмотреть на удаленный шаблон прокси, в котором вы кэшируете CFC, который реализует функциональность в области приложения, и имеете отдельный CFC «удаленный прокси», который намного легче и просто действует как прокси ( отсюда и название) между http-запросом и кешированным CFC.

В этом шаблоне ваш бизнес-объект (тот, у которого есть функция, выполняющая реальную работу) может иметь access=public (или пакет и т. Д.), Пока прокси имеет к нему доступ. Однако сам прокси должен иметь access=remote.

proxy.cfc

<cfcomponent output="false">
  <cffunction name="foobar" output="false" access="remote" hint="...">
    <cfargument name="arg1" type="string" required="true" />
    <!--- Application.foo is an instantiated object of foo.cfc --->
    <cfreturn Application.foo.foobar(argumentCollection=arguments) />
  </cffunction>
</cfcomponent>

Доступ по URL:

http://domain.com/path/to/proxy.cfc?method=foobar&arg1=some%20value&returnFormat=JSON



Метод 3. Сделай сам

Наконец, вы можете вручную реализовать вызов функции и возврат в шаблоне CFM. Этот метод не приводит к (небольшому) снижению производительности при написании CFC, но для вас будет больше печатать и дополнительные потенциальные точки отказа. Для этого включите свои функции в шаблон CFM и рассматривайте выходной поток только как поток текста, который будет возвращен браузеру.

Вы должны быть осторожны с управлением пробелами в возвращаемом значении (используйте output=false в определениях функций, рассмотрите возможность использования <cfsetting enableCFOutputOnly='true' и просто будьте осторожны с вашими интервалами в целом). Если ваш запрос jQuery ожидает возврата JSON, вам необходимо сериализовать его. (Если вам нужно сериализовать данные в JSON в ColdFusion 6 или 7, я рекомендую JSONUtil)

При таком подходе вы указываете свой запрос AJAX на файл .cfm с параметрами URL, а затем вам нужно написать код, который принимает эти параметры URL и передает их в функцию, а затем отображает (по сути, возвращается к запросу AJAX) результат функции.

foo.cfm

<cfsetting enableCFOutputOnly="true">
<cfparam name="arg1" default="defaultVal"/>

<cffunction name="foobar" output="false" access="remote" hint="...">
  <cfargument name="arg1" type="string" required="true" />
  ...
  <cfreturn someVar />
</cffunction>

<cfset variables.result = foobar(url.arg1) />
<cfoutput>#serializeJSON(variables.result)#</cfoutput>
16
Adam Tuttle 16 Июн 2009 в 12:05

Только что видел этот пост. Я использую cfc и jquery ajax для отображения кучи вычисленных значений. В моем cfc есть следующее:

<cfcomponent output="true">
<cfscript>
    this.init();
</cfscript>
     <cffunction name="init" access="public" returntype="any">
       <cfset variables.dsn = application.dsn>
        <cfreturn variables.dsn> 
     </cffunction>
     <cffunction name="getFinanceTerms" access="remote" output="true" returntype="void">
         <cfargument name="sales_price" type="numeric" required="yes">
         <cfargument name="interestRate" type="numeric" required="yes">
           <!--- some calculations here --->
         #arguments.salesPrice# <!--- just to have something displayed --->
         <cfreturn>
     </cffunction>
 </cfcomponent>

Я использую JQuery.ajax:

  $.ajax({
      type:"POST",
      url:"financeTerms.cfc?method=getFinanceTerms",
      data: "sales_price=55000&interestRate=5.99",
      cache:false,
      success: function(msg) {
      $("#someDiv").html(msg);
      }
  });

Возможно, еще кому-нибудь будет полезно ...

9
CFNinja 23 Июн 2009 в 18:59

Вам не обязательно использовать «AJAX» (в частности, XML-часть), но вы можете использовать вызов удаленного сервера:

$.get('/execute-function.cfm?func=whatever', function (result) { $('#result').html(result); });

Действительно зависит от того, что вам нужно делать с результатом. Приведенный выше код поместит результат HTML в div на вашей странице:

<div id="result"></div>

Вы можете использовать асинхронный вызов и анализировать XML, но я обнаружил, что они мне редко нужны.

3
razzed 16 Июн 2009 в 04:04

Вы можете попробовать тег <cfajaxproxy> в CF8, если хотите.

1
Henry 23 Июн 2009 в 20:13

Использование переменной ColdFusion в JavaScript - это мощное средство! Обязательно используйте

<cfoutput> var #toScript(ColdFusionVAR, 'javascriptVar')# </cfoutput>

Теперь вы можете ссылаться на свою переменную как javaScriptVar с помощью CFAJAXPROXY

Обязательно включите это в свой шаблон

<head> 
<cfajaxproxy cfc="cfc.yourclassname" jsclassname="jsCFCclassName">
</head>

Использование вашего класса на стороне JavaScript.

Вы бы нам так понравились.

var JS_CFC_Obj;

JS_CFC_Obj = new jsCFCclassName()

Теперь вы можете вызывать функции внутри этого cfc.

jsCFCclassName.functionName(javascript var);
0
Miguel-F 22 Янв 2013 в 20:07