Как сгенерировать GUID в VBScript?

Question

Я хочу сгенерировать строки GUID в VBScript. Я знаю, что в VBScript нет встроенной функции для его создания. Я не хочу использовать GUID, генерируемые случайным образом. Может быть, есть объект ActiveX, который можно создать с помощью CreateObject (), который обязательно будет установлен в (более новых) версиях Windows, которые могут генерировать GUID?

vbscript guid uuid

31

vividos 9 Июн 2009 в 12:02

Answer 1

Как я могу создать GUID с помощью скрипта? (in: Блог "Эй, сценарист!") говорит следующее:

Set TypeLib = CreateObject("Scriptlet.TypeLib")
Wscript.Echo TypeLib.Guid

Однако обратите внимание, что Scriptlet.TypeLib.Guid возвращает строку с завершающим нулем, что может привести к тому, что некоторые вещи будут игнорировать все, что находится после GUID . Чтобы исправить это, вам может потребоваться:

Set TypeLib = CreateObject("Scriptlet.TypeLib")
myGuid = TypeLib.Guid
myGuid = Left(myGuid, Len(myGuid)-2)
Wscript.Echo myGuid

33

Community 23 Май 2017 в 10:31

Answer 2

Set tlib = Server.CreateObject("Scriptlet.TypeLib")
strGuid = tlib.Guid

2

BobbyShaftoe 9 Июн 2009 в 08:07

Answer 3

' Returns a unique Guid on every call. Removes any cruft.
Function CreateGuid()
    CreateGuid = Left(CreateObject("Scriptlet.TypeLib").Guid,38)
End Function

8

BSalita 29 Сен 2012 в 00:00

Answer 4

Function CreateGUID
  Dim TypeLib
  Set TypeLib = CreateObject("Scriptlet.TypeLib")
  CreateGUID = Mid(TypeLib.Guid, 2, 36)
End Function

Эта функция вернет простой GUID, например 47BC69BD-06A5-4617-B730-B644DBCD40A9.

Если вам нужен GUID в формате реестра, например {47BC69BD-06A5-4617-B730-B644DBCD40A9}, измените последнюю строку функции на

CreateGUID = Left(TypeLib.Guid, 38)

51

Helen 8 Окт 2010 в 14:15

Как сгенерировать GUID в VBScript?

4 ответа

Похожие вопросы

Связанные вопросы

Новые вопросы

vbscript