Конвертировать из одного формата даты и времени в другой формат даты и времени

Question

Я хочу преобразовать время, которое берется в качестве аргумента скрипту Perl, в другой формат.

Вход имеет форму yyyyMMddHHmmss (например, 20190101235010).

Выходные данные должны иметь форму yyyy-MM-dd-HH:mm:ss (например, 2019-01-01-23:50:10).

Было бы лучше, если бы решение не использовало модули Perl (кроме POSIX).

perl unix-timestamp

0

vinodk89 30 Май 2019 в 18:58

Answer 1

Основной модуль Time :: Piece делает это легко.

use strict;
use warnings;
use Time::Piece;

# if input is the format you specified:
my $input = '20190101235010';
my $time = Time::Piece->strptime($input, '%Y%m%d%H%M%S');
print $time->strftime('%Y-%m-%d-%H:%M:%S'), "\n";

# if input is a unix epoch timestamp:
my $input = time;
my $time = gmtime $input;
print $time->strftime('%Y-%m-%d-%H:%M:%S'), "\n";

1

Grinnz 30 Май 2019 в 16:19

Answer 2

Вот несколько альтернатив, которые будут весьма полезны:

my $output =
    sprintf "%s-%s-%s-%s:%s:%s",
       unpack 'a4 a2 a2 a2 a2 a2',
          $input;

my $output = $input =~ s/^(....)(..)(..)(..)(..)(..)\z/$1-$2-$3-$4:$5:$6/sr;

my $output = $input =~ /^(....)(..)(..)(..)(..)(..)\z/s
  ? "$1-$2-$3-$4:$5:$6"
  : die("Bad input\n");

2

ikegami 30 Май 2019 в 19:38

Конвертировать из одного формата даты и времени в другой формат даты и времени

2 ответа

Похожие вопросы

Новые вопросы

perl