Как получить текущую таблицу в MS Word VBA?

Подпрограмма VBA в конце этого ответа показывает, как это сделать.

Он использует текущий выбор, сначала сворачивая его в начальную точку, чтобы не беспокоиться о многосегментном выборе:

Selection.Collapse Direction:=wdCollapseStart

Затем он проверяет этот выбор, чтобы убедиться, что он находится в таблице.

    If Not Selection.Information(wdWithInTable) Then
        MsgBox "Can only run this within a table"
        Exit Sub
    End If

После этого таблица становится доступной по ссылке Selection.Tables(1).

Приведенный ниже код был простым доказательством концепции, которая просто переключала каждую из начальных ячеек в каждой строке таблицы для вставки или удаления маркера вертикальной полосы.

Sub VertBar()
    ' Collapse the range to start so as to not have to deal with '
    ' multi-segment ranges. Then check to make sure cursor is '
    ' within a table. '
    Selection.Collapse Direction:=wdCollapseStart
    If Not Selection.Information(wdWithInTable) Then
        MsgBox "Can only run this within a table"
        Exit Sub
    End If

    ' Process every row in the current table. '
    Dim row As Integer
    Dim rng As Range

    For row = 1 To Selection.Tables(1).Rows.Count
        ' Get the range for the leftmost cell. '
        Set rng = Selection.Tables(1).Rows(row).Cells(1).Range

        ' For each, toggle text in leftmost cell. '
        If Left(rng.Text, 2) = "| " Then
            ' Change range to first two characters and delete them. '
            rng.Collapse Direction:=wdCollapseStart
            rng.MoveEnd Unit:=wdCharacter, Count:=2
            rng.Delete
        Else
            ' Just insert the vertical bar. '
            rng.InsertBefore ("| ")
        End If
    Next
End Sub