Я пытаюсь создать формулу в Google Sheets, которая работает как массив в первой ячейке столбца, отображая заголовок столбца, а также вызывает изменение текста в оставшейся части столбца в зависимости от диапазона номеров из другой ячейки. , Все это для массива, который работает с данными из формы Google.

До сих пор у меня было это работает, но вам нужно вручную перетащить его вниз:

=IF(K1=0, "Finalizado",IF(AND(K1>=0.000001, K1<0.49),"En Tiempo", IF(AND(K1>=0.5, K1<0.75),"Pendiente", iF(AND(K1>=0.75, K1<1), "Retrasado",iF(AND(K1>=1), "Fuera de Tiempo", "Undefined")))))

Затем, когда я превращаю его в массив, установленный в первой ячейке столбца, он проверяет только первые два условия, поэтому он показывает либо «finalizado», если указанная ячейка равна 0, либо «En tiempo», не говоря уже о что, как только он достигает точки, в которой больше нет ссылочных данных, он просто продолжает повторять 'finalizado' в каждой следующей ячейке.

={"Estatus";ArrayFormula(IF(K2:K=0, "Finalizado",IF(or(K2:K>=0.000001, K2:K<0.49),"En Tiempo",IF(and(K2:K>=0.5, K2:K<0.75),"Pendiente",iF(and(K2:K>=0.75, K2:K<1), "Retrasado",iF(AND(K2:K>=1), "Fuera de Tiempo"))))))}

Я думаю, что проблема может быть около третьего, если.

1
DEAGSMEX 12 Апр 2019 в 22:11

2 ответа

Лучший ответ
=ARRAYFORMULA(IF(LEN(K1:K), 
 IF(K1:K=0, "Finalizado",
 IF((K1:K>=0.000001) * (K1:K<0.49), "En Tiempo", 
 IF((K1:K>=0.5) * (K1:K<0.75), "Pendiente", 
 IF((K1:K>=0.75) * (K1:K<1), "Retrasado",
 IF(K1:K>=1, "Fuera de Tiempo", "Undefined"))))), ))

0

0
player0 12 Апр 2019 в 19:52
={"Estatus"; ARRAYFORMULA(IF(LEN(K2:K), 
 IF(K2:K=0, "Finalizado", 
 IF((K2:K>=0.5) * (K2:K<0.75), "Pendiente", 
 IF((K2:K>=0.75) * (K2:K<1), "Retrasado",
 IF(K2:K>=1, "Fuera de Tiempo",
 IF((K2:K>=0.000001) + (K2:K<0.49), "En Tiempo", "Undefined"))))), ))}

0

0
player0 12 Апр 2019 в 19:52