У меня проблемы с выполнением простой задачи. У меня есть следующий хеш хешей:

%hash = (
personA => {
    2017   => 1,
    2018   => 2,
},
personB => {
    2015   => 4,
    2013   => 28,
    2014   => 1, .
},
personC => {
    2013   => 3,
    2011   => 2,
    2012   => 45,
},
);

Я пытаюсь распечатать самый ранний год для каждого человека, например что-то вроде:

PersonA 2017

PersonB 2013

PersonC 2011

Кажется, что List::Util - лучший инструмент для этого, но я не могу найти пример для моих данных. У меня проблемы, потому что найденные мной решения пытаются отсортировать / распечатать первый уровень хэша (то есть personA и т. Д.), А не годы.

use strict;
use warnings;

my %hash;
my $hash; 

%hash = (
personA => {
    2017   => 1,
    2018   => 2,
},
personB => {
    2015   => 4,
    2013   => 28,
    2014   => 1,
},
personC => {
    2013   => 3,
    2011   => 2,
    2012   => 45,
},
);

use List::Util qw(min);
my $min = min keys %hash;
$hash = {$min => $hash->{$min}};
2
Izzy 18 Сен 2018 в 16:38

2 ответа

Лучший ответ

Прокрутите людей. Затем разыменуйте хэш каждого человека, чтобы получить список лет:

use warnings;
use strict;
use List::Util qw(min);

my %people = (
personA => {
    2017   => 1,
    2018   => 2,
},
personB => {
    2015   => 4,
    2013   => 28,
    2014   => 1,
},
personC => {
    2013   => 3,
    2011   => 2,
    2012   => 45,
},
);

for my $person (sort keys %people) {
    my $min = min(keys %{ $people{$person} });
    print "$person $min\n";
}

Выходы:

personA 2017
personB 2013
personC 2011
4
vanHoesel 18 Сен 2018 в 15:24

Вы можете вообще не использовать какой-либо модуль, сохраняя при этом простоту.

use warnings;
use strict;

my %hash = (
    personA => {
        2017 => 1,
        2018 => 2,
    },
    personB => {
        2015 => 4,
        2013 => 28,
        2014 => 1,
    },
    personC => {
        2013 => 3,
        2011 => 2,
        2012 => 45,
    },
);

foreach my $person ( sort keys %hash ) {
    printf( "%s %d\n", $person, ( sort keys %{ $hash{$person} } )[0] );
}

(sort keys% {$ hash {$ person}}) [0] - сортирует ключи в порядке возрастания (по умолчанию), а затем получает первый из них.

3
Pradeep 18 Сен 2018 в 13:56