Используя Google Sheets, я пытаюсь выяснить, как выполнить сопоставление индекса, чтобы найти значение на основе двух критериев ... затем, когда я продолжу использовать формулу, она исключит все ранее возвращенные значения.

Предполагая, что во всех примерах 3 столбца ...

Лист 1:

a  b  <blank>
a  b  <blank>

Я пытаюсь вернуть значения в столбец, ища как a, так и b на другом листе ... но я хочу, чтобы каждый раз возвращалось только одно новое значение.

Лист 2:

a  b  c
a  b  d
a  b  e

Итак, для первого листа я бы хотел, чтобы это было:

a  b  c
a  b  d

Я уверен, что это как-то возможно, просто не знаю, как это сделать ...

1
vyzion87 7 Дек 2019 в 03:18

1 ответ

Лучший ответ

Пытаться:

=ARRAYFORMULA(IFNA(VLOOKUP(A1:A&B1:B&COUNTIFS(A1:A&B1:B, A1:A&B1:B, ROW(A1:A), "<="&ROW(A1:A)), 
 {Sheet2!A1:A&Sheet2!B1:B&COUNTIFS(Sheet2!A1:A&Sheet2!B1:B, Sheet2!A1:A&Sheet2!B1:B, 
 ROW(Sheet2!A1:A), "<="&ROW(Sheet2!A1:A)), Sheet2!C1:C}, 2, 0)))

0

0
player0 7 Дек 2019 в 03:33
Ого, это здорово !! Не могли бы вы разбить логику на словах, чтобы я мог понять? Также можно ли это сделать по 3 критериям?
 – 
vyzion87
9 Дек 2019 в 05:04
Конечно. COUNTIFS(A1:A&B1:B, A1:A&B1:B, ROW(A1:A), "<="&ROW(A1:A)) будет подсчитывать объединенное значение A&B, поэтому любое следующее такое же значение получит следующее число, затем оно будет добавлено к A&B, поэтому результат будет >> ab1, ab2, то же самое сделано на другом листе, поэтому результат будет ab1, ab2, ab3. мы добавляем третий столбец из Sheet2 с этим в массив VR { } и оборачиваем все вышеперечисленное в VLOOKUP (обратите внимание, что простой vlookup никогда не сможет вывести значение d в ячейке C2). и да, это возможно даже по 3 критериям - логика та же
 – 
player0
9 Дек 2019 в 12:44
Спасибо, теперь мне просто неясно по этой части: "<=" & ROW (A1: A) ... что именно делает эта часть?
 – 
vyzion87
11 Дек 2019 в 09:27
Это та часть, которая фактически считает вхождение в каждой следующей строке, и если сравнение меньше или равно, оно увеличит счетчик на единицу. в основном он считает повторение каждого уникального значения в наборе
 – 
player0
11 Дек 2019 в 10:09