Сортировка вкладок в Excel, проблема с синтаксисом VBA

Сортировка возрастающих листов

• Процедура SortIncrementingSheetsTEST является примером использования (вызова) основной процедуры SortIncrementingSheets.
• Для работы основной процедуры SortIncrementingSheets требуется процедура GetLastInteger.
• Процедура GetLastInteger возвращает последнее целое число (последние последовательные цифры в виде числа), найденное в строке.
• Процедура GetLastIntegerTEST является примером использования (вызова) процедуры GetLastInteger. Он печатает 13 в окне Immediate, поскольку 13 является последним целым числом в строке примера Sheet1(013).
• По сути, все имена листов и соответствующие им последние целые числа записываются в Keys и Items dictionary, которые затем используются при сортировке листов. Раскомментируйте строки Debug.Print, чтобы лучше понять, как работает процедура, просмотрев результаты в окне "Немедленное".
• Сортировка в процедуре основана на следующей статье Microsoft Docs от MVP Tom Urtis:
  Sort Worksheets Alphanumerically by Name

Option Explicit

Sub SortIncrementingSheetsTEST()
    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    SortIncrementingSheets wb
End Sub

Sub SortIncrementingSheets( _
        ByVal wb As Workbook)
' Needs 'GetLastInteger'.
    
    If wb Is Nothing Then Exit Sub
    
    Dim dict As Object: Set dict = CreateObject("Scripting.Dictionary")
    dict.CompareMode = vbTextCompare
    
    Dim sh As Object
    
    For Each sh In wb.Sheets
        dict.Add sh.Name, GetLastInteger(sh.Name)
    Next sh
    'Debug.Print Join(dict.Keys, ",")
    'Debug.Print Join(dict.Items, ",")
    
    Dim shCount As Long: shCount = wb.Sheets.Count

    Application.ScreenUpdating = False
    
    Dim i As Long
    Dim j As Long
    
    For i = 1 To shCount - 1
        For j = i + 1 To shCount
            If dict(wb.Sheets(j).Name) < dict(wb.Sheets(i).Name) Then
                wb.Sheets(j).Move Before:=wb.Sheets(i)
                'Debug.Print "Moved '" & wb.Sheets(i).Name & "' from '" _
                    & j & " to " & i & "'."
            End If
        Next j
    Next i

    Application.ScreenUpdating = True

    MsgBox "Sheets sorted.", vbInformation

End Sub

Function GetLastInteger( _
    ByVal SearchString As String) _
As Long
    
    Dim nLen As Long: nLen = Len(SearchString)
    
    Dim DigitString As String
    Dim CurrentChar As String
    Dim n As Long
    Dim FoundDigit As Boolean
    
    For n = nLen To 1 Step -1
        CurrentChar = Mid(SearchString, n, 1)
        If CurrentChar Like "#" Then ' it's a digit
            DigitString = CurrentChar & DigitString
            If Not FoundDigit Then
                FoundDigit = True
            End If
        Else ' it's not a digit
            If FoundDigit Then
                Exit For
            End If
        End If
    Next n
    
    If FoundDigit Then
        GetLastInteger = CLng(DigitString)
    Else
        GetLastInteger = -1
    End If

End Function

Sub GetLastIntegerTEST()
    Debug.Print GetLastInteger("Sheet1(013)")
End Sub